CTB Beta

CTB Beta

6 Pages
←
1
2
3
4
→
Last »

You cannot start a new topic
You cannot reply to this topic

#21 AndruRC

Novice

Job: Member
Posts: 51

24 May 2016 - 06:54 AM

Think0028, on 20 May 2016 - 06:54 PM, said:

2) There are no more command delays - your command fires immediately. Instead, your delay is subtracted from your next turn - your ATB will drop farther the longer the wait of the command you use.

Known bugs:
1) I have been completely unable to reproduce this, but if you choose a command for a character and they're somehow hit by Stop before firing the action, which should be impossible, and you find they never get a turn again, even after curing Stop, which should also be impossible, and they never leave their ready animation, which is like triply impossible, please report that. Even though you won't. Because it's impossible.

While playing on the Veldt for the first time, I did notice Cyan get hit after inputting a Bushido command, but before Dispatch actually triggered. The attack didn't cause Stop, but it very well could have.

Sadly I don't have any clips to confirm, but it happened. Pretty sure it was a Leafer in the 2x Leafer, 1x Raven formation.

#22 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

24 May 2016 - 06:55 AM

Aw MAN.

EDIT: So I'm sure this is fixable, but it'll take me a bit to get an exact fix out because it's a very nuanced problem.

#23 Bluerobin427

Casual Gamer

Job: Member
Posts: 102

24 May 2016 - 07:46 AM

I am so freaking psyched to play through 1.7.4 with this.

#24 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

24 May 2016 - 10:57 AM

In case people are curious, here's the problem as far as I can determine, and a brief lecture on how the system works.

Every tick, every actor on the battlefield has their ATB gauge increase, in this order:
Monster #6
Monster #5
Monster #4
Monster #3
Monster #2
Monster #1
Player #4
Player #3
Player #2
Player #1

If a player's gauge fills, their command window opens up. When a command is input, the player character enters the Wait Queue. Then, each tick, their 'wait gauge' fills up until it is full, and on that tick they take the action. If there's no wait (like in CTB), the very next tick has the action happen.

With CTB, when a gauge is full, combat ticks are paused, and with the current implementation combat ticks are unpaused when a command is input and a player character enters the wait queue. I thought there'd be no simultaneous actions because I made it so ticks don't happen until someone enters the wait queue. The problem is the following, which is pretty obvious if you think about it:

Tick #1: Monster's ATB fills. They enter the wait queue, which due to the code I wrote *unblocks the ATB gauges from filling*. So any party member's ATB can fill on the same tick, and they'll get their command, and they'll be second in the wait queue. Both parties enter their ready animation this tick being empties from the queue.
Tick #2: Monster's action fires, because they were checked first in the combat tick.

There's two solutions, and I'm exploring which one would be easier:
1) Entering the action queue directly instead of the wait queue if your action has no delay, so that you don't have to wait for the next tick and I can block the next tick until the action is finished.
2) If an action is added to either the wait queue or the action queue, prevent ATB gauges from filling up for the rest of this tick.

I prefer 1), and am working on it. The tricky part is making sure that there's no holes where you think you could get an action, but your character is about to die anyways.

#25 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

24 May 2016 - 09:13 PM

New version up that's better in every way. Let me know if a monster ambushes you between queueing and attacking again. Also make sure Jump, Palidor, and running away work. Install on a fresh copy of 1.7.4, and just don't load a mid-battle save state. Hell, even if you do I think it'll be fine in a turn or two.

#26 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 06:50 AM

There's something wonky with the code you posted. I edited your disassembly into xkas-compatible syntax and tried it out. The IPS patch works fine, but when I assemble your code, all ATB is paused all the time.

I double checked that I hadn't inserted the branch labels in the wrong places (and without branch labels, just the branch operands, which xkas is fine with). I do think it's a faulty branch somewhere.

Edit:
I should mention I am trying this on a vanilla FF3us 1.0 ROM. I ported your nATB changes to it and it worked well with the CTB beta 1 you originally posted in this thread, like I posted earlier.

Edit2: I tried it on BNW1.7.4 too. IPS: fine, ASM: time frozen eternally.

Here's my edit of your code:

Spoiler

org $C201C6 
LDA #$7F ;for the code i'm about to run
JSR $6594

org $C2067E
db $C0

org $C2068F
db $C0

org $C20691
db $C0

org $C20983
JSR $65D1 ; after death and wakeup go to half gauge, not empty

org $C20AB4
NOP #3  ; make morph use up a turn like normal

org $C21124
JMP $657D

org $C21130
NOP #2 ; just get rid of that whole 'only call once every two frames' thing

org $C21193 
JMP $65AB

org $C21196
; the old code at 1193, except we store 00 instead of FF
LDA $3AC8,X
LSR ; cut in half so that gauges fill up at half speed 
CLC
ADC $3AB4,X 
STA $3AB4,X
SEP #$20
BCS zero_322c
XBA
CMP $322C,X
BCC exit2 ;(branching to a RTS)
zero_322c:
STZ $322C,X
NOP ; cover the last one off instruction

org $C211BA
exit2:

org $C211BD
LDA $1280 ; load if we should block ATB
JSR $65DF ; if we can, halve speed, add to current ATB
STA $3218,X ; store it

org $C211D1
JMP $65BD ; zero atb if 1280 clear, FF that shit otherwise

org $C221D6
JSR $65FE

org $C2247D
STZ $1280 ; setup

org $C24E6F
JSR $65C8 ;jump to 65CC to also clear the 1280, since the current person is no longer blocking turns

org $C25BE0
NOP #2 ; NOPS to VASTLY improve run speed

org $C2657D ; movable to any free space, but the rest really shouldn't move. we jump to 118B if we're skipping the turn, 1129 if we aren't. 2F41 in accumulator to start
ORA $3A8F
BNE Dont_Continue ;branch to label Don't Continue - either menu open or animation playing
LDA $1280
AND #$02 ;only check if it's 2, meaning someone has a full ATB and is about to enter the wait queue
BEQ Continue ;branch to label Continue - no menu open, no animation playing, no turn up
LDA $2F45 ;Characters running
BEQ Dont_Continue ;branch to label Don't Continue - no one running, turn up, so no ATB progression
Continue:
JMP $1129 
Dont_Continue:
JMP $118B 

org $C26594
CLC
ADC $3219,X ;add 7F to lower byte
BMI branch1
SBC $3219,X ;subtract 7F, oops our bad
BRA branch2
branch1:
SBC $322C,X ;subtract wait timer from atb top byte
STA $3219,X
branch2:
STA $322C,X
RTS

org $C265AB
REP #$20
LDA $3018,X
BIT $3F2C
BEQ not_jumping ; if they aren't jumping, don't bother waiting
JMP $1196 ;(handle wait ticking normally if they're one of those mamsy pamsy jumpers)
not_jumping:
SEP #$20
JMP $11AF ;(let the action go through if it's not jump)

org $C265BD
STZ $3219,X ; so only the first person gets to actually enter the Gauge Full state
LDA #$02
STA $1280 ; set 1280 to prevent anyone from getting a turn this tick
JMP $11D4

org $C265C8
LDA #$01 ; when someone's adding to the wait queue, we just block ATB increasing and not combat ticks. if they jump then we take care of that later
STA $1280
INC $3A65 ; replaced code
RTS

org $C265D1
LDA $3219,X
BNE reset_gauge ;if the ATB is full, then clear 1280 because they're no longer blocking turns
STZ $1280
reset_gauge:
LDA #$80
STA $3219,X ; make gauge half full
RTS

org $C265DF
BNE exit ; if it's nonzero we aren't increasing ATB
LDA $3018,X
BIT $3F2C
BEQ jumping ; if they are jumping, no ATB for you
increase_atb:
LDA $3AC8,X
LSR ;(we have ATB increase in accumulator)
ADC $3218,X
exit:
RTS

jumping:
SEP #$20
LDA $2F45 ;Characters running
REP #$20
BEQ pause_atb ; if they aren't running, you don't get ATB
CPX #$08
BCC increase_atb ; if party member running and this is monster, you get atb anyways
pause_atb:
LDA $3218,X
RTS

org $C26602
TSB $3F2C ; replaced code
STZ $1280 ; stop blocking
RTS

Somewhat unrelated note: at C2/11A9, there's a 90 0E, but shouldn't it be 90 0F since your code is shifted one byte? I labeled the RTS at C2/11BA and branched to that label, and the assembler does produce a 90 0F. Whether this is 90 0E or 90 0F has no impact on the issue I've described in this post, but I was wondering, because a faulty branch should crash the game. It doesn't, which suggests this code isn't being executed.

#27 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 07:29 AM

1) Good catch on the 90 0E: it doesn't crash because 3A is a one-instruction operation, DEC A. It should be a 90 0F.
2) I am a poor imitation of a programmer who just writes directly on the ROM and makes notes for the disassembly. Let me look for what I missed.

#28 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 07:56 AM

6594 is missing a STZ $1280 in the disassembly. That will break it in exactly that manner. I'm away from my tools but a diff check with the IPS should reveal the error there. You'll even note the space between 94 and AB is 24 bytes, but the current disassembly only has 21.

#29 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 08:51 AM

Good god, man, why is it that so many talented coders insist on using the equivalent of punch cards for their ROM hacking?

I used to type code just like I saw it in disassemblies, then look up opcodes from a reference sheet and punch raw hex into Windhex by hand, too. When I started using xkas it was a goddamn revelation. I don't miss updating branches by hand. At all.

The only problem you'll have with using an assembler is kicking yourself too hard for not adopting it earlier.

#30 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 08:58 AM

Haha, yeah, it was born out of me literally having no clue what tools were out there and never working up the effort to investigate. Thanks for the tip! I'll check it out next time I whip something up.

Add-on: the 90 0E is fixed in my local version of the patch, but the bug has literally no effect - the accumulator loads a new value before it does anything. The fix will go out with the next version of this patch if there is one, or will just be fixed when it gets incorporated into something else.

#31 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 10:22 AM

Upon examining the IPS, and comparing it to the code, there's another discrepancy in C2/6594. The IPS has two additional instructions, an LDA #$FF and the STZ $1280 you mentioned. But it is also missing the STA $322C,X that is present in the source (commented out, below).

The previous version had LDA #$FF / STA $322C,X. This new version has STZ $1280 replacing the STA $322C,X, but the LDA #$FF is still in there. I have to admit I don't fully understand what's going on in this part of the code so I can't tell if you intended to remove the STA $322C,X or not.

[snip]
branch2:
LDA #$FF
;STA $322C,X
STZ $1280
RTS

Anyway, I added the STZ $1280 to my .asm (as in the code above) and the problem persists. :/ I'll have a look around the IPS with IPS peek and see if there are more differences.

#32 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 11:00 AM

Hrm. I'm gonna go dig some more, then. The $322C removal was intentional, but I'm not sure what else is missing.

EDIT: Sigh. The IPS file is missing the command delay changes for Morph, Defend, and Row. That new version is coming out tonight, then.

#33 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 11:24 AM

C2/21D6:
20 FE 65 JSR $65FE

That entry is completely wrong. The correct code, and what's in the IPS, is:

C2/21D6:
20 02 66 JSR $6602.

Time to learn xkas! The original post is updated with what should be the correct disassembly now.

#34 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 12:48 PM

So I went through the IPS file with IPS Peek and disassembled every entry with Geiger's debugger, and now it finally works.

~~I didn't add in the comments~~ (edit: I did), but here's the full code of every change in the IPS file. I added in the Wait Timer edits from the first version of the patch, too.

By the way, xkas syntax is pretty simple. I'm sure you've found it already, but here's the documentation: http://bin.smwcentra.../6138/xkas.html

There are some undocumented quirks in how xkas handles branches. You might expect "BRA $10" to be converted to a PC relative address, but xkas assembles that as a straight "80 10". Which is why the code below works without branch labels.

Edit: I went through the code and added Think's comments, added branch and jump labels, fixed some errors in the disassembly, added Think's changes to the Wait Timers (and all the Wait Timers from vanilla BNW). It's now fully labeled and relocatable by simply changing the !freespace define.

Spoiler

;Think's CTB beta v2
;Requires Think's nATB

hirom
;header
!freespace = $C2657D  ;(requires 140 bytes)

org $C201C6
LDA #$7F              ;for the code i'm about to run
JSR label_C26594

;Time to wait (BNW)
org $C2067B
db $10   ;(Fight)
db $10   ;(Item)
db $20   ;(Magic)
db $C0   ;(Morph)     ;Changed for CTB

db $00   ;(Revert)
db $00   ;(Steal)
db $00   ;(Capture)
db $20   ;(SwdTech)

db $10   ;(Throw)
db $20   ;(Tools)
db $20   ;(Blitz)
db $00   ;(Runic)

db $20   ;(Lore)
db $10   ;(Sketch)
db $20   ;(Control)
db $20   ;(Slot)

db $10   ;(Rage)
db $00   ;(Leap)
db $00   ;(Mimic)
db $10   ;(Dance)

db $C0   ;(Row)       ;Changed for CTB
db $00   ;(Def.)
db $C0   ;(Jump)      ;Changed for CTB
db $20   ;(X-Magic)

db $20   ;(GP Rain)
db $40   ;(Summon)
db $10   ;(Health)
db $10   ;(Shock)

db $00   ;(Possess)
db $00   ;(MagiTek)
db $00   ;(?)
db $00   ;(?)  

org $C20981
LDA #$80
JSR label_C265D1      ;after death and wakeup go to half gauge, not empty

org $C20AB4
NOP #3                ;make morph use up a turn like normal

org $C21124
JMP label_C2657D

org $C21129
label_C21129:

org $C21130
NOP #2                ;just get rid of that whole 'only call once every two
                      ;frames' thing

org $C2118B
label_C2118B:

org $C21193
JMP label_C265AB
  
;the old code at 1193, except we store 00 instead of FF
label_C21196:
LDA $3AC8,X
LSR A                 ;cut in half so that gauges fill up at half speed      
CLC        
ADC $3AB4,X
STA $3AB4,X
SEP #$20   
BCS branch1
XBA        
CMP $322C,X
BCC exit              ;(branching to a RTS)
branch1:
STZ $322C,X
NOP                   ;cover the last one off instruction
label_C211AF:

org $C211BA
exit:

org $C211BD
LDA $1280             ;load if we should block ATB
JSR label_C265DF:     ;if we can, halve speed, add to current ATB
;STA $3218,X          ;store it (this is in vanilla already)

org $C211D1
JMP label_C265BD      ;zero atb if 1280 clear, FF that shit otherwise
label_C211D4:

org $C221D6
JSR label_C26602

org $C2247D
STZ $1280   ;setup

org $C24E6F
JSR label_C265C8      ;jump to 65C8 to also clear the 1280, since the current
                      ;person is no longer blocking turns

org $C25BE0
NOP #2                ;NOPS to VASTLY improve run speed


org !freespace        ;from now on, these are moveable/can take more space if
                      ;necessary. we jump to 118B if we're skipping the turn,
                      ;1129 if we aren't. 2F41 in accumulator to start
label_C2657D:
ORA $3A8F  
BNE Dont_Continue     ;branch to label Dont_Continue - either menu open or
                      ;animation playing    
LDA $1280  
AND #$02              ;only check if it's 2, meaning someone has a full ATB and
                      ;is about to enter the wait queue   
BEQ Continue          ;branch to label Continue - no menu open, no animation
                      ;playing, no turn up    
LDA $2F45             ;Characters running  
BEQ Dont_Continue     ;branch to label Dont_Continue - no one running, turn up,
                      ;so no ATB progression    
Continue:
JMP label_C21129
Dont_Continue:
JMP label_C2118B

label_C26594:
CLC        
ADC $3219,X           ;add 7F to lower byte
BMI branch2
SBC $3219,X           ;subtract 7F, oops our bad
BRA $06
branch2:    
SBC $322C,X           ;subtract wait timer from atb top byte
STA $3219,X
LDA #$FF   
STZ $1280  
RTS

label_C265AB:
REP #$20   
LDA $3018,X
BIT $3F2C  
BEQ branch3           ;if they aren't jumping, don't bother waiting    
JMP label_C21196      ;(handle wait ticking normally if they're one of those
                      ;mamsy pamsy jumpers)  
branch3:
SEP #$20   
JMP label_C211AF      ;(let the action go through if it's not jump)  

label_C265BD:
STZ $3219,X           ;so only the first person gets to actually enter the
                      ;Gauge Full state
LDA #$02   
STA $1280             ;set 1280 to prevent anyone from getting a turn this tick  
JMP label_C211D4

label_C265C8:
LDA #$01              ;when someone's adding to the wait queue, we just block
                      ;ATB increasing and not combat ticks. if they jump then
                      ;we take care of that later  
STA $1280  
INC $3A65             ;replaced code  
RTS

label_C265D1:
LDA $3219,X
BNE branch4           ;if the ATB is full, then clear 1280 because they're no
                      ;longer blocking turns    
STZ $1280
branch4:  
LDA #$80   
STA $3219,X           ;make gauge half full
RTS

label_C265DF:
BNE branch5           ;if it's nonzero we aren't increasing ATB    
LDA $3018,X
BIT $3F2C  
BNE branch5           ;if they are jumping, no ATB for you    
LDA $3AC8,X
LSR A                 ;(we have ATB increase in accumulator)      
ADC $3218,X
RTS

branch5:        
SEP #$20   
LDA $2F45             ;Characters running  
REP #$20   
BEQ branch6           ;if they aren't running, you don't get ATB    
CPX #$08   
BCS $EB               ;if party member running and this is monster, you get atb
                      ;anyways    
branch6:
LDA $3218,X
RTS

label_C26602:
TSB $3F2C             ;replaced code  
STZ $1280             ;stop blocking 
RTS

Edit: Fixed some stuff that was disassembled wrong. It looks the same in the ROM, so it still works. It just didn't make sense to humans.

#35 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 01:40 PM

Thanks for the tips! And yeah, it's very obvious now that the IPS file is missing the wait changes. I'll add those in and get the next version out, and then I'll get to work on improving my work environment.

#36 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 02:52 PM

I think the IPS is also missing this:

org $C25BE0
NOP #2 ;NOPS to VASTLY improve run speed

Also, this branch is actually 0Fh bytes long

BNE $0D ;branch to label Dont_Continue - either menu open or animation playing

#37 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 02:55 PM

Huh. Then... why am I running faster anyways? That part will have to be investigated.

And I'll fix that branch too, thanks.

#38 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 03:22 PM

Aw, what the hell. I cleaned up the ASM and I figured I might as well update my post. Think, I invite you to use this for future work on CTB. I'd rather not disassemble another behemoth IPS patch.

cakes, on 25 May 2016 - 12:48 PM, said:

Went through the code and added Think's comments, added branch and jump labels, fixed some errors in the disassembly, added Think's changes to the Wait Timers (and all the Wait Timers from vanilla BNW). It's now fully labeled and relocatable by simply changing the !freespace define.

Spoiler

;Think's CTB beta v2
;Requires Think's nATB

hirom
;header
!freespace = $C2657D  ;(requires 140 bytes)

org $C201C6
LDA #$7F              ;for the code i'm about to run
JSR label_C26594

;Time to wait (BNW)
org $C2067B
db $10   ;(Fight)
db $10   ;(Item)
db $20   ;(Magic)
db $C0   ;(Morph)     ;Changed for CTB

db $00   ;(Revert)
db $00   ;(Steal)
db $00   ;(Capture)
db $20   ;(SwdTech)

db $10   ;(Throw)
db $20   ;(Tools)
db $20   ;(Blitz)
db $00   ;(Runic)

db $20   ;(Lore)
db $10   ;(Sketch)
db $20   ;(Control)
db $20   ;(Slot)

db $10   ;(Rage)
db $00   ;(Leap)
db $00   ;(Mimic)
db $10   ;(Dance)

db $C0   ;(Row)       ;Changed for CTB
db $00   ;(Def.)
db $C0   ;(Jump)      ;Changed for CTB
db $20   ;(X-Magic)

db $20   ;(GP Rain)
db $40   ;(Summon)
db $10   ;(Health)
db $10   ;(Shock)

db $00   ;(Possess)
db $00   ;(MagiTek)
db $00   ;(?)
db $00   ;(?)  

org $C20981
LDA #$80
JSR label_C265D1      ;after death and wakeup go to half gauge, not empty

org $C20AB4
NOP #3                ;make morph use up a turn like normal

org $C21124
JMP label_C2657D

org $C21129
label_C21129:

org $C21130
NOP #2                ;just get rid of that whole 'only call once every two
                      ;frames' thing

org $C2118B
label_C2118B:

org $C21193
JMP label_C265AB
  
;the old code at 1193, except we store 00 instead of FF
label_C21196:
LDA $3AC8,X
LSR A                 ;cut in half so that gauges fill up at half speed      
CLC        
ADC $3AB4,X
STA $3AB4,X
SEP #$20   
BCS branch1
XBA        
CMP $322C,X
BCC exit              ;(branching to a RTS)
branch1:
STZ $322C,X
NOP                   ;cover the last one off instruction
label_C211AF:

org $C211BA
exit:

org $C211BD
LDA $1280             ;load if we should block ATB
JSR label_C265DF:     ;if we can, halve speed, add to current ATB
;STA $3218,X          ;store it (this is in vanilla already)

org $C211D1
JMP label_C265BD      ;zero atb if 1280 clear, FF that shit otherwise
label_C211D4:

org $C221D6
JSR label_C26602

org $C2247D
STZ $1280   ;setup

org $C24E6F
JSR label_C265C8      ;jump to 65C8 to also clear the 1280, since the current
                      ;person is no longer blocking turns

org $C25BE0
NOP #2                ;NOPS to VASTLY improve run speed


org !freespace        ;from now on, these are moveable/can take more space if
                      ;necessary. we jump to 118B if we're skipping the turn,
                      ;1129 if we aren't. 2F41 in accumulator to start
label_C2657D:
ORA $3A8F  
BNE Dont_Continue     ;branch to label Dont_Continue - either menu open or
                      ;animation playing    
LDA $1280  
AND #$02              ;only check if it's 2, meaning someone has a full ATB and
                      ;is about to enter the wait queue   
BEQ Continue          ;branch to label Continue - no menu open, no animation
                      ;playing, no turn up    
LDA $2F45             ;Characters running  
BEQ Dont_Continue     ;branch to label Dont_Continue - no one running, turn up,
                      ;so no ATB progression    
Continue:
JMP label_C21129
Dont_Continue:
JMP label_C2118B

label_C26594:
CLC        
ADC $3219,X           ;add 7F to lower byte
BMI branch2
SBC $3219,X           ;subtract 7F, oops our bad
BRA $06
branch2:    
SBC $322C,X           ;subtract wait timer from atb top byte
STA $3219,X
LDA #$FF   
STZ $1280  
RTS

label_C265AB:
REP #$20   
LDA $3018,X
BIT $3F2C  
BEQ branch3           ;if they aren't jumping, don't bother waiting    
JMP label_C21196      ;(handle wait ticking normally if they're one of those
                      ;mamsy pamsy jumpers)  
branch3:
SEP #$20   
JMP label_C211AF      ;(let the action go through if it's not jump)  

label_C265BD:
STZ $3219,X           ;so only the first person gets to actually enter the
                      ;Gauge Full state
LDA #$02   
STA $1280             ;set 1280 to prevent anyone from getting a turn this tick  
JMP label_C211D4

label_C265C8:
LDA #$01              ;when someone's adding to the wait queue, we just block
                      ;ATB increasing and not combat ticks. if they jump then
                      ;we take care of that later  
STA $1280  
INC $3A65             ;replaced code  
RTS

label_C265D1:
LDA $3219,X
BNE branch4           ;if the ATB is full, then clear 1280 because they're no
                      ;longer blocking turns    
STZ $1280
branch4:  
LDA #$80   
STA $3219,X           ;make gauge half full
RTS

label_C265DF:
BNE branch5           ;if it's nonzero we aren't increasing ATB    
LDA $3018,X
BIT $3F2C  
BNE branch5           ;if they are jumping, no ATB for you    
LDA $3AC8,X
LSR A                 ;(we have ATB increase in accumulator)      
ADC $3218,X
RTS

branch5:        
SEP #$20   
LDA $2F45             ;Characters running  
REP #$20   
BEQ branch6           ;if they aren't running, you don't get ATB    
CPX #$08   
BCS $EB               ;if party member running and this is monster, you get atb
                      ;anyways    
branch6:
LDA $3218,X
RTS

label_C26602:
TSB $3F2C             ;replaced code  
STZ $1280             ;stop blocking 
RTS

Edit: I forgot to say, I added placeholder branch (edit: and jump/jsr) labels. Feel free to rename them to something more descriptive.
~~Oh, and the !freespace define is unusable because I didn't actually add any jump/jsr labels. I'll remove it.~~ It's usable now.

#39 Think0028

Improbability Breaker

Job: Member
Posts: 1,702

25 May 2016 - 03:32 PM

You're a hero and I love you.

#40 seibaby

Novice

Job: Member
Posts: 36

25 May 2016 - 04:12 PM

I apparently can't leave well enough alone either. I added the jump/jsr labels; no more hard jumps. The code is now fully labeled and fully relocatable simply by changing the !freespace define.

I updated the previous posts with the code.

By the way, I'm not sure the Wait Timer values I copied are the correct ones. I copied them from BNW, then added your changes from CTB beta 1, but it doesn't look right to me. Anyway, that's why I added all of them, so that it's easily changeable.

Think0028, on 25 May 2016 - 03:32 PM, said:

You're a hero and I love you.

Hehe, thanks. I appreciate what you've done with this awesome patch and I'm happy to help. I'm going to be using this whenever I play FFVI from now on and never look back. Madsiur actually sent me FFVI song data for the FFX battle theme, too.

Share this topic:

6 Pages
←
1
2
3
4
→
Last »

You cannot start a new topic
You cannot reply to this topic

Insane Difficulty: CTB Beta - Insane Difficulty

CTB Beta

#21 AndruRC

#22 Think0028

#23 Bluerobin427

#24 Think0028

#25 Think0028

#26 seibaby

#27 Think0028

#28 Think0028

#29 seibaby

#30 Think0028

#31 seibaby

#32 Think0028

#33 Think0028

#34 seibaby

#35 Think0028

#36 seibaby

#37 Think0028

#38 seibaby

#39 Think0028

#40 seibaby

Share this topic:

Delete Post

Insane Difficulty: CTB Beta - Insane Difficulty

CTB Beta

Share this topic:

Delete Post

USERNAME

PASSWORD